note
	description: "[
		Describes this particular location in VITP
	]"
	author: "Jimmy J. Johnson"

class
	BAY_OF_BENGAL

inherit

	SEA_AREA
		redefine
			make
		end

create
	make

feature {NONE} -- Initialization

	make (a_game: like game)
			-- Initialize Current
		do
			Precursor (a_game)
			nationality := {NATIONALITY_CONSTANTS}.us
			defining_position := [30, 330]
		end

feature -- Access

	name: STRING_8 = "Bay of Bengal"
			-- The displayed name for this widget

	defining_position: TUPLE [x, y: INTEGER_32]
			-- The x- and y-coordinate (in millimeters) of Current's
			-- position relative to the top-left corner of the board.

	allied_poc: INTEGER = 1
			-- The number of points gained by the Allied player if he
			-- controls this area at the end of a turn

	japanese_poc: INTEGER = 2
			-- The number of points gained by the Japanese player if he
			-- controls this area at the end of a turn

	adjoining_ports: LINEAR [PORT]
			-- All the ports that adjoin this sea area
		local
			p: LINKED_SET [PORT]
		once
			create p.make
			p.extend (game.ceylon)
			p.extend (game.andaman_islands)
			Result := p.linear_representation
		end

	adjacent_sea_areas: LINEAR [SEA_AREA]
			-- All the sea areas which touch this one
		local
			s: LINKED_SET [SEA_AREA]
		once
			create s.make
			s.extend (game.indonesia)
			s.extend (game.indian_ocean)
			Result := s.linear_representation
		end

end
