note
	description: "[
		Describes this particular location in VITP
	]"
	author: "Jimmy J. Johnson"

class
	JAPANESE_ISLANDS

inherit

	SEA_AREA
		redefine
			make
		end

create
	make

feature {NONE} -- Initialization

	make (a_game: like game)
			-- Initialize Current
		do
			Precursor (a_game)
			nationality := {NATIONALITY_CONSTANTS}.japanese
			defining_position := [420, 110]
		end

feature -- Access

	name: STRING_8 = "Japanese Islands"
			-- The displayed name for this widget

	defining_position: TUPLE [x, y: INTEGER_32]
			-- The x- and y-coordinate (in millimeters) of Current's
			-- position relative to the top-left corner of the board.

	allied_poc: INTEGER = 3
			-- The number of points gained by the Allied player if he
			-- controls this area at the end of a turn

	japanese_poc: INTEGER = 3
			-- The number of points gained by the Japanese player if he
			-- controls this area at the end of a turn

	adjoining_ports: LINEAR [PORT]
			-- All the ports that adjoin this sea area
		local
			p: LINKED_SET [PORT]
		once
			create p.make
			p.extend (game.yokosuka_navy_yard)
			p.extend (game.okinawa)
			Result := p.linear_representation
		end

	adjacent_sea_areas: LINEAR [SEA_AREA]
			-- All the sea areas which touch this one
		local
			s: LINKED_SET [SEA_AREA]
		once
			create s.make
			s.extend (game.aleutian_islands)
			s.extend (game.central_pacific_ocean)
			s.extend (game.marianas_islands)
			s.extend (game.indonesia)
			Result := s.linear_representation
		end

end